Material

Aluminium

• Elastizitätsmodul $E=70\,\mathrm{GPa}$
• Querkontraktionszahl $\nu=0{,}3$

Geometrie

Balken mit rechteckigem Querschnitt

• Länge $L=1000\,\mathrm{mm}$
• Breite $b=30\,\mathrm{mm}$
• Höhe $h=60\mathrm{mm}$

Randbedingungen

• feste Einspannung an der linken Seite (y=0)
• Einzelkraft auf der oberen Kanten am Ende des Balkens $F=1000\,\mathrm{N}$

Gesucht

1. Die maximale Durchbiegung $u_{max}$
2. Die maximale Spannung $\sigma_{max}$

• analytische Lösung

ANSYS Mechanical APDL

APDL-Code

FINISH
/CLEAR

! START PRE-PROCESSING
/PREP7

dim_x = 30 ! [mm] 
dim_y = 1000 ! [mm]
dim_z = 60 ! [mm]
em = 70e3 ! [MPa]
nu = 0.3
esize = 15 ! [mm]
kraft = 1000 ! [N]

! MATERIAL DEFINIEREN
MP,EX,1,em
MP,PRXY,1,nu

! ELEMENTTYP DEFINIEREN
ET,1,SOLID186

! GEOMETRIE ERSTELLEN
BLOCK,0,dim_x,0,dim_y,0,dim_z

! VERNETZT
MAT,1
TYPE,1
ESIZE,esize
VMESH,ALL

! START SOLUTION
/SOLU

! RANDBEDINGUNGEN ANBRINGEN

! EINSPANNUNG
	! KNOTEN SELEKTIEREN 
NSEL,S,LOC,Y,0
	! RB ANBRINGEN AUF SELEKTRIERTE KNOTEN
D,ALL,ALL,0

!KRAFT ANBRINGEN
!	KNOTEN SELEKTIEREN 
NSEL,S,LOC,Y,dim_y
NSEL,R,LOC,Z,dim_z
*GET,node_count,NODE,NUM,COUNT
!	RB ANBRINGEN AUF SELEKTRIERTE KNOTEN
F,ALL,FZ,-kraft/node_count

! LOESEN DES GLEICHUNGSSYSTEMS
ALLS
OUTRES,ALL,ALL
SOLVE

! START POST-PROCESSING
/POST1

! VERSCHIEBUNG in y-Richtung
PLNSOL,U,Z

! SPANNUNG in y-Richtung
PLNSOL,S,Y

Spannung als Pfad ausgeben

siehe FAQ / Zusammenfassungen (Pfad Teil)

• Workflow Beispiel (in pfad.txt speichern)

Lösung (Datei speichern)

! Pfadplot
! PFAD DEFINITION
PADELE,ALL !löscht alle vorherigen Pfade (für Schleifen benötigt)
PATH,laengs,2,,100 !Pfad mit 2 Punkten und 100 Schritten definieren
PPATH,1,,dim_x/2,0,dim_z ! Pfadpunkt 1 (x=0, y=0, z=0) definieren
PPATH,2,,dim_x/2,dim_y,dim_z ! Pfadpunkt 2 (x=l/2, y=0, z=0) definieren
PMAP,ACCURATE ! Pfadpunkte am Anfang und Ende in kleineren Einteilungen
PDEF,s_y,S,Y,NOAV ! Spannung in y

! PFAD AUSGABE
/FORMAT,,E,15,5 ! Einstellung fuer die Ausgabe
/PAGE,,,-1 ! Einstellung fuer die Ausgabe
/HEADER,OFF,OFF,OFF,OFF,ON,OFF! Einstellung fuer die Ausgabe
/OUTPUT,pfad,txt ! Datei zum schreiben öffnen
PRPATH,s_y ! Pfad in Datei schreiben
/OUTPUT ! Datei zum schreiben schließen